14

PDP11 doesn't provide an AND instruction – just XOR. What is the usual PDP-11 assembly code to implement an AND, i.e. the PDP-11 assembler equivalent of the C code a & b please?

What I'm looking for in particular is the PDP-11 assembly equivalent to the C code if (a == (a & b))… my ‘bit twiddling’ is very rusty. The variable a is a set of ‘requirements’, with each bit meaning a specific capability is required, while b is the set of capabilities available. As long as b has at least the same bits set as a, then the condition is satisfied. If it has more, then the check should also pass. However if at least one bit set in a isn't set in b then the condition is not satisfied.

Improve this question
4
  • Thanks for all the answers. I've used the simplest from Chris Dodd which works great Commented Jan 19 at 10:50
  • 1
    So the short version of the answer is that your "just xor" is not really true - you've overlooked BIS, BIC and BIT, and in particular COM+BIC accomplishes AND. Commented Jan 20 at 5:17
  • @nate. ?? I only mentioned xor as being provided by the instruction set and 'and' and 'or' are not provided. I knew/know about bic, bis and bit but I wanted to know how to use these to provide the 'and' instruction I was looking for as I said my 'bit twiddling' was rusty - which the given answers do (thanks to those that responded). I was thinking 'in c' and hadn't recognised that just using bic does what I want. com, bic, cmp was what I was originally retying to remember but as was pointed out bic, bne is all that is needed. Commented Jan 20 at 13:25
  • 1
    BIS is OR. The choice of assembler mnemonic does not change that. (And BIC is AND NOT, of course) Commented Jan 20 at 14:39

3 Answers 3

Reset to default
18

As already observed, 'and' is used in different cases. As an assembly programmer, I'd write one of the following.

To test a bit or bits known at assembly time:

BIT #FLAG,FUBAR
BNE 20$  ; flag is set

To clear a bit or bits known at assembly time:

BIC #FLAG,FUBAR  ; effectively 'and not FLAG'

To isolate that same bit or bits:

BIC #^CFLAG,FUBAR  ; ^C is bitwise complement

Real 'and' of two variable values: R0 := A /\ B
Clear in A the bits that are not set in B

MOV A,R0
MOV B,R1
COM R1
BIC R1,R0

As a system-level programmer, this last case was the least common. I was mostly interested in setting, testing, and clearing known bits or groups of bits. The mask was only variable if this was a common subroutine called with different sets of flags.

The case posed by the OP is therefore:

MOV A,R0   ; required capabilities
COM R0     ; uninteresting capabilities
MOV B,R1   ; actual capabilities
BIC R0,R1  ; remove uninteresting capabilities
CMP A,R1   ; all requirements set?
BEQ ...    ; branch if yes

or better yet, as suggested by Chris Dodd:

MOV A,R0    ; working copy of requirements
BIC B,R0    ; leaves unsatisfied requirements
BNE FAIL    ; fail if any unsatisified
Improve this answer
5
  • 1
    +2 to "As a system-level programmer, this last case was the least common. I was mostly interested in setting, testing, and clearing known bits or groups of bits" Except, IMHO it's true for all programming. AND as itself is only useful to extract groups of bits. It's a rather rare case having multi bit variables in a single word and use is therefore as rare. Though, very early on we did this more often to crunch down data in ever shorter disk records - or squeeze down save data between transactions when all we had to store continuation data per user was a 64 byte buffer ::)) Commented Jan 18 at 22:39
  • 9
    Note that the OPs code is equivalent to if (0 == (a & ^b)) which can be implemented with just BIC+BNE. C compiler optimizers of the time could do that automatically. Commented Jan 19 at 1:04
  • 3
    Right you are -- a & ~b isolates the required capabilities that b does not have. So, BIC B,A; BNE FAIL (with apppriate register use if you don't want to clobber a). Not only is this shorter code, it's easier to explain what is going on. Added to answer. Thanks. Commented Jan 19 at 1:54
  • Thanks Chris. That works perfectly for what I want. Commented Jan 19 at 10:48
  • 1
    w.r.t. "and is used in different cases" see also this answer - noting also that the excellent book referred to there is available online (link in the answer). Commented Jan 23 at 23:35
9

Not to speak off the top of my head, going to https://www.pcjs.org/machines/dec/pdp11/1170/4mb/ and compiling

int a, b;
extern c();
d() {
    if (a == (a & b))
        c();
}

yields the body of d() as follows:

_d:
jsr     r5,rsave
mov     _a,r0
mov     _b,r1
com     r1
bic     r1,r0
cmp     _a,r0
jne     L1
jsr     pc,_c
L1:jmp  rretrn

In other words, AND is done as complementing one of the operands and clearing the bits of the other using the result of the complement.

Improve this answer
10
  • This is is clearly what this compiler emits but I suppose that a more efficient sequence would be to compute a == (a & b) as (b & ~a) == 0 using a single BIC b,a and branch on Z. Commented Jan 18 at 18:40
  • @doynax You must have meant (~b & a) == 0 Commented Jan 18 at 18:50
  • Scratch that. I am clearly confused. I guess that it would need to be computed as (~a & ~b) == 0. Commented Jan 18 at 19:07
  • 3
    GCC still supports PDP-11; we could see if it optimizes any better. Not provided on godbolt, though, so you'd have to build it. Commented Jan 19 at 1:47
  • 1
    @user3840170 The question did not ask "where is a PDP-11 simulator?". And why comment regarding textual changes if your reputation allows to edit if the first place? Commented Jan 23 at 16:14
0

When you only need the condition flags based on a AND b (which should be enough to cover your example), you can use BIT - It performs the logical operation and sets the flag accordingly, but doesn't change any of the operands.

Improve this answer
2
  • 3
    TST does not do what the OP wants. It does the equivalent of if ((a & b) != 0) rather than if ((a & b) == a). Commented Jan 18 at 17:02
  • 4
    @LeoB. - the answer says BIT, not TST. I assume a typo by you. But BIT still doesn't work as a single instruction. Commented Jan 18 at 19:01

You must log in to answer this question.

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.