www-client/opera-developer: automated bump (124.0.5701.1)

Signed-off-by: Matt Jolly <kangie@gentoo.org>
author: Matt Jolly <kangie@gentoo.org> 2025-10-31 10:26:29 +1000
committer: Matt Jolly <kangie@gentoo.org> 2025-10-31 10:26:29 +1000
commit: 30ce08717dceec4769d4349ed3416c5cea869570 (patch)
tree: f3224a12e699b8db2b9918815b4e90d1e3a5bd4c
parent: www-client/opera-beta: remove old (diff)
download: gentoo-30ce08717dceec4769d4349ed3416c5cea869570.tar.gz
gentoo-30ce08717dceec4769d4349ed3416c5cea869570.tar.bz2
gentoo-30ce08717dceec4769d4349ed3416c5cea869570.zip
2 files changed, 167 insertions, 0 deletions
diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index e303fc7b049b..8da579eda2e6 100644
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1,3 +1,4 @@
 DIST opera-developer_123.0.5658.0_amd64.deb 134407564 BLAKE2B c03977497aa369640d5e47e37fd9c8d54baaf9cf3b611744f83b5b2041fa4c0a8155f1e70f6b9e89e40c68ae2b2c260921a348c588dd0227a4ef377c1d2314e8 SHA512 ce9a16a8aae9da4714e65d72c27e86d9362d9aec15cc90bdecf9fa8fe8ef8dc42d3eb474fb401a853fd43721f9f5519dd2a7de8bd8fab09b3615b398e3f761a6
 DIST opera-developer_124.0.5670.0_amd64.deb 135277560 BLAKE2B 6962f789f8d5944aeae0b55fe3588e66e3bc264ef4fecfe9039a8b7e5fbd67d479ade4a520deec9bb90bbdb270f8f657e3c69a49700b68a306c05cf916402786 SHA512 47fa9e87e0b62726344e57a1c6cdfdbe579b8a242e64836327a8eef14deeff3951a252f40a1fdb69e81a4388353dbc955a852f9106862ebce9e8a4e04bd6e700
 DIST opera-developer_124.0.5678.0_amd64.deb 135316652 BLAKE2B ae365c266e07c5d69a7d06a62d18b74f100f065264d3afc8d950d8c66d8fdf021653023fb6dae57154afa534476cf05b9c8294b59711ac61716321dc799f9d4a SHA512 b832a7140b33573ae4e7df03bb204581bc9e881f86c494edd03c2a347add27a03789495542ecd54308a25e077400adf11134901119f6467a1ccfd23e2a766f6f
+DIST opera-developer_124.0.5701.1_amd64.deb 136285524 BLAKE2B 75707ada73362a834f8a5d6bef0f997acb06f7c01d1b6d3761bbc990bcffcab3503c5300411c09a1c6079d7a3a8d3ac3b2d15623091c4ffa0ccaa009ce1af039 SHA512 66bddef2461ac8c741ee799b851e9ed54bb0e2bde3ea99f413a47ff9408fa967969585bdb098be91607a6bbda22ae8cfc4f23a5c0d4d124c8880cf729554fb86
diff --git a/www-client/opera-developer/opera-developer-124.0.5701.1.ebuild b/www-client/opera-developer/opera-developer-124.0.5701.1.ebuild
new file mode 100644
index 000000000000..bc9285883f4c
--- /dev/null
+++ b/www-client/opera-developer/opera-developer-124.0.5701.1.ebuild
@@ -0,0 +1,166 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHROMIUM_LANGS="
+	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	inherit rpm
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	inherit unpacker
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+# Commit ref from `strings libffmpeg.so | grep -F "FFmpeg version"` matches this Chromium version
+# used to select the correct ffmpeg-chromium version (corresponds to a major version of Chromium)
+# Does not need to be updated for every new version of Opera, only when it breaks
+CHROMIUM_VERSION="138"
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}"
+S=${WORKDIR}
+
+LICENSE="OPERA-2018"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+IUSE="+ffmpeg-chromium +proprietary-codecs +suid qt6"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+	proprietary-codecs? (
+		!ffmpeg-chromium? ( >=media-video/ffmpeg-6.1-r1:0/58.60.60[chromium] )
+		ffmpeg-chromium? ( media-video/ffmpeg-chromium:${CHROMIUM_VERSION} )
+	)
+	qt6? ( dev-qt/qtbase:6[gui,widgets] )
+"
+
+QA_PREBUILT="*"
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		dosym ../../usr/$(get_libdir)/chromium/libffmpeg.so$(usex ffmpeg-chromium .${CHROMIUM_VERSION} "") \
+			  /${OPERA_HOME}/libffmpeg.so
+	fi
+
+	rm "${OPERA_HOME}/libqt5_shim.so" || die
+	if ! use qt6; then
+		rm "${OPERA_HOME}/libqt6_shim.so" || die
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "/${OPERA_HOME}/opera_sandbox"
+}
author	Matt Jolly <kangie@gentoo.org>	2025-10-31 10:26:29 +1000
committer	Matt Jolly <kangie@gentoo.org>	2025-10-31 10:26:29 +1000
commit	30ce08717dceec4769d4349ed3416c5cea869570 (patch)
tree	f3224a12e699b8db2b9918815b4e90d1e3a5bd4c
parent	www-client/opera-beta: remove old (diff)
download	gentoo-30ce08717dceec4769d4349ed3416c5cea869570.tar.gz gentoo-30ce08717dceec4769d4349ed3416c5cea869570.tar.bz2 gentoo-30ce08717dceec4769d4349ed3416c5cea869570.zip